使用 Mathematica 实现HOMO与LUMO轨道的3D同步可视化及自动排版保存 - 计算化学公社

在化学反应研究中，最高占据分子轨道（HOMO）和最低未占据分子轨道（LUMO）的理解和分析至关重要。传统上，我们依赖 Gaussian09/16 软件来计算这些轨道数据，这一过程涉及将计算结果的 chk 文件通过 formchk 命令转换为 fchk 文件，再使用 cubegen 命令将 fchk 文件转化为 cube 文件，最后进行可视化处理。

然而，这一流程并不尽如人意，尤其是在需要同时处理多个分子的轨道数据时。每当需要统一调整多个分子的视角以保持一致性时，工作量急剧增加，手动调整变得异常繁琐。此外，完成这些步骤后，我们还需进行复杂的图像排版工作，这在处理大量分子时更是耗时耗

面对这些繁琐且耗时的步骤，我想到了一个高效且简洁的解决方案：结合 Mathematica 和 Gaussian 16，实现一键式分子轨道可视化和自动排版。

首先，我们继续利用 Gaussian 16 进行精确的轨道数据计算。接着，借助 Mathematica 强大的数据处理和图形展示能力，将这些复杂的数据转换成直观的3D图像。这一过程不仅简化了数据转换，还提高了整体的工作效率

Clear["Global`*"]
(*设置nb文件所在的位置*)
SetDirectory[NotebookDirectory[]];
(*log文件*)
s0Log = "s0.log";
(*cube 文件*)
s0HomoCube = "s0_homo.cube";
s0LumoCUbe = "s0_lumo.cube";
s1HomoCube = "s1_homo.cube";
s1LumoCube = "s1_lumo.cube";
(*输出图片*)
s0HomoPic = "s0_homo.png";
s0LumoPic = "s0_LumoPic.png";
s1HomoPic = "s1_HomoPic.png";
s1LumoPic = "s1_LumoPic.png";
DynamicModule[{vp = {1.3, -2.4, 2.0}, vv = {0, 0, 1}},
logFun[file_] :=
Import["s0.log", "GaussianLog"] //
MoleculePlot3D[#, ViewPoint -> Dynamic[vp],
ViewVertical -> Dynamic[vv], SphericalRegion -> True] &;
cubeFun[file_] :=
Import[file, "Graphics3D", ContourStyle -> {Red, Blue},
ViewPoint -> Dynamic[vp], ViewVertical -> Dynamic[vv],
SphericalRegion -> True];
(*=== 定义分子模型图 ===*)
s03D = logFun[s0Log];
s0Homo = cubeFun[s0HomoCube];
s0Lumo = cubeFun[s0LumoCUbe];
s1Homo = cubeFun[s1HomoCube];
s1Lumo = cubeFun[s1LumoCube];
(*=== 创建组合图形布局 ===*)
(*定义一个应用样式的函数*)
styledText1[text_] :=
Style[text, FontFamily -> "Times New Roman", FontSize -> 18];
styledText2[text_] :=
Style[text, FontFamily -> "Times New Roman", FontSize -> 12];
(*应用样式到具体文本*)
s0Text = styledText1["s0"];
s1Text = styledText1["s1"];
homoText = styledText2["HOMO"];
lumoText = styledText2["LUMO"];
(* ===构建 combinedGraphics ===*)
combinedGraphics = Grid[
{{s03D, s0Homo, s0Text, s0Lumo, s1Homo, s1Text, s1Lumo},
{" ", homoText, " ", lumoText, homoText, " ", lumoText}},
Alignment -> Center, Spacings -> {1, 0.3},
Dividers -> {{{False, True, False, False, True, False, False},
False}}, FrameStyle -> Directive[Dashed]];
(*=== 动态面板 ===*)
Panel@Column[{
Dynamic@combinedGraphics,
Button["Save",
Export[s0HomoPic, s0Homo, Background -> None];
Export[s0LumoPic, s0Lumo, Background -> None];
Export[s1HomoPic, s1Homo, Background -> None];
Export[s1LumoPic, s1Lumo, Background -> None];
Export["s0s1_homolumo.png", combinedGraphics, "PNG",
Background -> None];
Method -> "Queued"]}]]

复制代码

(* === 1. 定义文件路径 === *)
path1 = "http://pic.wxyh.top/C3H4O2-esp.cube"; (*导入esp.cube文件的路径*)
path2 = "http://pic.wxyh.top/C3H4O2-Potential.cube"; (*导入Potential.cube文件的路径*)
(* === 2. 导入体积数据 === *)
espCube = Import[path1, "VolumetricData"]; (*导入esp.cube文件*)
potentialCube = Import[path2, "VolumetricData"]; (*导入Potential.cube文件*)
(* === 3. 获取数据信息 === *)
espData = espCube["Data"]; (*从esp.cube文件中提取数据*)
potentialData = potentialCube["Data"]; (*从Potential.cube文件中提取数据*)
dataRange = espCube["DataRange"]; (*获取数据的范围*)
(* === 4. 处理数据 === *)
espDataNormal = Normal[espData]; (*将espData数据标准化*)
potentialDataNormal = Normal[potentialData]; (*将potentialData数据标准化*)
(* === 5. 绘图 === *)
mole = Import[path1, "Molecule"]; (*导入分子数据*)
moleplot = MoleculePlot3D@mole; (*生成分子模型*)
surface = ListContourPlot3D[espData[[1]], Contours -> 0.03 {-1, 1}, DataRange -> dataRange] // DiscretizeGraphics; (*生成等值面*)
potentialPlot = ListSliceDensityPlot3D[potentialData[[1]], surface, DataRange -> dataRange,
ColorFunction -> ({Opacity[0.8], Blend["M10DefaultDensityGradient", #1]} &), PlotLegends -> Automatic]; (*生成静电势图*)
Show[moleplot, potentialPlot] (*显示分子模型和静电势图*)

复制代码

(, 下载次数 Times of downloads: 61)